som unieke waarden

popipipo · #1 4 februari 2012, 15:38

@bsalv
http://www.worksheet.nl/forumexcel/v...tml#post601609

Hier heb je een keurige oplossing gegeven voor unieke waarde tellen.
Dit lukt ook met getallen.

Maar ik zat even te experimenteren om nu de som van die unieke getallen te krijgen.
Ik dacht dat onderstaande code misschien wel zou werken maar dat doet hij helaas niet.

Code:

Function somuniek(bereik)
  Dim SomUniekBereik As New Collection, c As Range
  On Error Resume Next
  For Each c In bereik.Cells
    If c <> "" Then SomUniekBereik.Add Item:=c.Value, Key:=CStr(c.Value)
  Next
  On Error GoTo 0
  somuniek = SomUniekBereik.Sum
End Function

Waar moet ik nu wat aanpassen.

Dus rij is bv 1, 1, 1, 2, 2, 3, 3, 4
Het resultaat moet dan wezen 10 (1+2+3+4=10)

bsalv · #2 4 februari 2012, 15:44

zoiets bijvoorbeeld

Code:

Function somuniek(bereik)
  Dim SomUniekBereik As New Collection, c As Range, it As Variant
  On Error Resume Next
  For Each c In bereik.Cells
    If c <> "" And IsNumeric(c) Then SomUniekBereik.Add Item:=c.Value, Key:=CStr(c.Value)
  Next
  On Error GoTo 0
  For Each it In SomUniekBereik
  somuniek = somuniek + CDbl(it)
  Next
End Function

snb · #3 4 februari 2012, 15:52

of

Code:

Function F_count_distinct_snb(c01)
 F_count_distinct_snb = Evaluate("Sum(N(countif(offset(" & c01.Cells(1).Address & ",,,row(" & c01.Address & "))," & c01.Address & ")=1))")
End Function

voor verwante funkties zie hier.

popipipo · #4 4 februari 2012, 16:13

Kort maar krachtig,
Maar niet wat ik vroeg.

Met jou formule krijg ik het aantal verschillende waarden en mijn vraag was duidelijk de som van alle verschillende waarden:

Citaat:

Dus rij is bv 1, 1, 1, 2, 2, 3, 3, 4
Het resultaat moet dan wezen 10 (1+2+3+4=10)

bsalv · #5 4 februari 2012, 16:54

@snb
misschien kan je weer eens iets goochelen
het is de bedoeling dat ieder getal misschien wel vaker voorkomt, maar die mag maar 1 keer in de som mee opgeteld worden !!!

Code:

Function F_Sommeer_Verschillende_Waarden_BSALV(c01)
  For j = 1 To UBound(c01.Value)
    c02 = c02 & "~|~" & Join(Application.Index(c01.Value, j), "~|~")
  Next
  c02 = Mid(c02, 4, Len(c02) - 4)
  Do
    i = InStr(1, c02, "~|~")
    If i <> 0 Then
      c03 = Left(c02, i - 1)
      If IsNumeric(c03) Then som = som + CDbl(c03)
      If i > 1 Then
        Do
          l = Len(c02)
          c02 = Replace(c02, "~|~" & c03 & "~|~", "~|~")
        Loop While l <> Len(c02)
      End If
      c02 = Mid(c02, i + 3, Len(c02))
    End If
  Loop While i <> 0
  F_Sommeer_Verschillende_Waarden_BSALV = som
End Function

GiMe · #6 4 februari 2012, 17:25

In formulevorm :

Code:

=SOMPRODUCT((A1:A8)*(AANTAL.ALS(VERSCHUIVING($A$1;RIJ(A1:A8)-RIJ(A1);;AANTAL(A1:A8)-(RIJ(A1:A8)-RIJ(A1));1);A1:A8)=1))

met in A1:A8 de getallen

dirktimm · #7 4 februari 2012, 17:37

Hallo Willem,

Of:

Code:

=SOM(ALS(INTERVAL(A1:A8;A1:A8)>0;A1:A8))

link: http://support.microsoft.com/kb/268001/nl

Groet

Dirk

bsalv · #8 4 februari 2012, 17:45

of hoe je via Parijs en Rome rond ook kunt gaan koffie drinken bij de buren

popipipo · #9 4 februari 2012, 17:54

Toch leuk dat er zoveel reactie komen om mij te helpen met mijn experimentje.
De oplossing met formules had ik reeds (op de zelfde site gevonden).
Stukje bij beetje wil ik ook iets meer van vba weten vandaar deze vraag.
Er zijn inmiddels 7 reacties op mijn vraag geweest maar #2 was reeds voldoende.

Toch allemaal bedankt.

snb · #10 4 februari 2012, 18:16

Daarom ten overvloede:

Code:

Function F_count_distinct_snb3(c01)
  F_count_distinct_snb3 = Evaluate("Sumproduct((countif(offset(" & c01.Cells(1).Address & ",,,row(" & c01.Address & ")-row(" & c01.Cells(1).Address & ")+1)," & c01.Address & ")=1)*(" & c01.Address & "))")
End Function

en

Code:

Function Function F_sum_distinct_snb4(c01)
    F_sum_distinct_snb4 = Evaluate("sum(if(frequency(" & c01.Address & "," & c01.Address & ")>0," & c01.Address & "))")
End Function

Discussietools
Printversie tonen Deze pagina e-mailen
Weergave
Lineaire weergave Switchen naar hybride weergave Switchen naar vertakte weergave

Soortgelijke discussies
Discussie	Auteur	Forum	Reacties	Laatste bericht
Unieke waarden en aantal	Hanzsel	Vragen	9	18 april 2012 18:02
Unieke waarden weergeven na filter	R.Jorna	Afgehandelde vragen	9	21 oktober 2011 16:52
Unieke waarden in lijst verwijderen	Timmo	Afgehandelde vragen	25	18 juni 2009 20:02
unieke waarden filteren uit 2 lijsten	maze00	Afgehandelde vragen	5	8 april 2009 10:31
ID's koppelen aan unieke waarden.	Ids	Afgehandelde vragen	8	28 november 2008 11:21